刚刚心血来潮，编了一个国际域名查询的功能页面，比较简单，没有做什么美化和修饰，主要利用了服务器端的XMLHTTP访问第三方服务器实现域名查询功能。
有兴趣的朋友可以美化一下放在自己的网站上对外提供域名查询服务了。：）
国际域名查询系统：
<%
Option Explicit
Dim Domain,jnkcHTML,jnkcOutPut
Domain = Request("domain")
If Domain & "x" = "x" Then
jnkcHTML = ""
Else
jnkcHTML = GetDetail("http://www.networksolutions.com/cgi-bin/whois/whois?SearchType=do&STRING=" & Domain)
'这里也可以换成其他查询网址，但是下面的判断也应作相应修改。
End If
Function GetDetail(jnkcUrl)
Dim jnkcXMLHTTP
Set jnkcXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
jnkcXMLHTTP.Open "GET", jnkcUrl, False, "", ""
jnkcXMLHTTP.Send
GetDetail = jnkcXMLHTTP.ResponseText
Set jnkcXMLHTTP = Nothing
End Function
If InStr(jnkcHTML,"Incorrect domain name query") > 1 Then
jnkcOutPut = "请输入正确的域名格式，如： CSDN.NET"
ElseIf InStr(jnkcHTML,"This name is available for registration") > 1 Or InStr(jnkcHTML,"No match") > 1 Then
jnkcOutPut = Domain & " 没有被注册，你可以马上注册"
ElseIf InStr(jnkcHTML,"Record expires on") > 1 Then
jnkcOutPut = Domain & " 已经被注册，以下是该域名的注册信息："
jnkcOutPut = jnkcOutPut & GetInfo()
ElseIf jnkcHTML = "" Then
jnkcOutPut = ""
Else
jnkcOutPut = "域名服务器出错"
End If
Function GetInfo()
Dim jnkcStart,jnkcEnd,jnkcLength
jnkcStart = InStr(jnkcHTML,"<pre")
jnkcEnd = InStr(jnkcHTML,"</pre>")
jnkcLength = jnkcEnd-jnkcStart+6
If jnkcStart*jnkcEnd*jnkcLength > 1 Then
GetInfo = Mid(jnkcHTML,jnkcStart,jnkcLength)
GetInfo = DelA(GetInfo)
Else
GetInfo = "发生未知错误"
End If
End Function
Function DelA(jnkcValue)
Dim jnkcRegExp
Set jnkcRegExp = new RegExp
jnkcRegExp.IgnoreCase = true
jnkcRegExp.Global = True
jnkcRegExp.Pattern = "(<A[^>]*>)(.*)(<\/A>)"
DelA = jnkcRegExp.Replace(jnkcValue,"$2")
Set jnkcRegExp = Nothing
End Function
%>
<html>
<head>
<title>江南昆虫国际域名查询系统</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<meta name="Generator" content="EditPlus">
<meta name="Author" content="JnKc">
<meta name="Keywords" content="">
<STYLE TYPE="text/css">
*{font-size:12px}
</STYLE>
</head>
<body>
<table width="600" align="center">
<tr>
<td><form method="get">
<h3 align="center">江南昆虫国际域名查询系统</h3>
请输入要查询的域名：（如：csdn.net） <input name="domain"><input type="submit" value="查询"><br>
本系统支持的域名为：[.com,.net,.org,.edu,.tv,.us,.name,.cc,.bz,.ws,.de,.be,.info,.biz]
</form>
<hr><%= jnkcOutPut %>
</td>
</tr>
</table>
</body>
</html> |